[sara1975]

DREAMWEAVERCS3 - inserimento modulo invio dati da web
ciao a tutti, è la prima volta che vengo in questo sito, mi sono appena registrata nella disperata ricerca di un aiuto!!

sto realizzando un sito internet ma una ditta, il sito è quasi giunto al termine, l'ho realizzato con dreamweaver cs3 lavoro con mac, ho il dominio su aruba hosting windows.

il mio problema è il seguente: non sono capace a fare la pagina "contattaci"
pensavo fosse immediato, che bastasse inserire il modulo con nome, cognome note ecc. mettere il pulsante "invia" e che tutto fosse a posto ma ho visto che non è cosi....

o meglio, facendo come ho fatto io mi invia i dati ma usa outlook e scrive i dati in maniera orrenda "NOME=&COGNOME=&COGNOME2=&COGNOME3=&COGNOME4=& COGN OME5=&COGNOME6=&invio=Invia"

io invece volevo che i dati partissero dal sito internet e arrivassero al mio cliente scritti bene

come si fa??

ho un libro, parla di pagine asp, di database in access (che non ho neanche) ...non ci si capisce niente...ti prego puoi aiutarmi??

potete aiutarmi??

[Delo]

Ciao Sara e benvenuta

veniamo subito al tuo problema: per creare un form contatti occorre creare due pagina, una che avrà il compito di far riempire i campi dall'utente e una seconda pagina chiamata invio.asp (ad esempio) che ti permetterà di inviare i dati dell'utente a un e-mail a tua scelta.
Entro breve ti allego in questa discussione i due file per creare il form, è molto semplice non ti preoccupare

[sara1975]

ciao delo, grazie moltissimo per l'aiuto...detto cosi sembra facile! venerdi devo portare la prima bozza di questo sito...credi di potermi aiutare a capire come fare queste due pagine, o meglio, come fare funzionare questo modulo? grazie sara

[Delo]

Questo è il codice della seconda pagina incaricata di inviare la mail

Copia e incolla il testo in una file e chiamalo invia.asp

Codice PHP:

<!--METADATA TYPE="typelib" UUID="CD000000-8B95-11D1-82DB-00C04FB1625D" NAME="CDO for Windows 2000 Type Library" -->
<!--METADATA TYPE="typelib" UUID="00000205-0000-0010-8000-00AA006D2EA4" NAME="ADODB Type Library" -->
<%
DIM corpoMessaggio, numeroCampi, invioA, invioDa, nomeDominio, indirizzoIp, modulo, browserSistemaOperativo

'* voce da modificare con il proprio indirizzo email
mail="e-mail destinatario"

nome=request("nome")
cognome=request("cognome")
messaggio=request("messaggio")

if nome="" or cognome="" or messaggio="" then
%>
<script>
alert('Attenzione: compliare tutti i campi richiesti!');
history.go(-1);
</script>
<%
response.end
end if

invioA = mail

'* voce da modificare con un indirizzo email che funga da mittente:
'* in caso di errore riceverete notifica a questo indirizzo un MAILER-DAEMON
'* dato che cdosys supporta questa notifica
invioDa = ""&mail&""

'------------fine modifiche necessarie------------------

nomeDominio = Request.ServerVariables("HTTP_HOST")
indirizzoIp = Request.ServerVariables("REMOTE_ADDR")
modulo = Request.ServerVariables("HTTP_REFERER")
browserSistemaOperativo = Request.ServerVariables("HTTP_USER_AGENT")

'*rilevo i campi del form

FOR numeroCampi = 1 TO (Request.Form.Count() - 0)
IF NOT Request.Form(numeroCampi) = "" THEN
corpoMessaggio = corpoMessaggio & vbCrLf & Request.Form.Key(numeroCampi) & " = " & Trim(Request.Form(numeroCampi))
END IF
NEXT

'* creo gli oggetti cdosys sul server e li gestisco

DIM iMsg, Flds, iConf

Set iMsg = CreateObject("CDO.Message")
Set iConf = CreateObject("CDO.Configuration")
Set Flds = iConf.Fields

Flds(cdoSendUsingMethod) = cdoSendUsingPort
Flds(cdoSMTPServer) = "smtp.aruba.it"
Flds(cdoSMTPServerPort) = 25
Flds(cdoSMTPAuthenticate) = cdoAnonymous ' 0
Flds.Update

With iMsg
Set .Configuration = iConf
.To = invioA
.From = invioDa
.Sender = invioDa
.Subject = "Richiesta di contatto dal sito Web"
.TextBody = "Questi i dati inseriti dall'utente nel modulo del sito "& vbCrLf & corpoMessaggio & ""

.Send
'response.end
End With
Response.Redirect("contatti-ok.asp")
%> 


[Delo]

Mentre la pagina dove troveremo i campi vuoti da compilare lo chiameremo contatti.asp

Codice PHP:

<form name="contatti" method="post" action="invio.asp">    
Nome: <input name="nome" size="30" type="text" id="nome" />
Cognome: <input name="cognome" size="30" type="text" id="cognome" />
E-Mail <input name="email" size="30" type="text" id="email" />
Messaggio: <textarea name="messaggio" cols="40" rows="8"></textarea>
<input name="button"  type="submit" value="Invia"/>
<input name="reset" type="reset" value="Reset" />
</form>